Tutoriel Excel sur la fonction VLOOKUP avec des exemples de formules (2024)

Aujourd'hui, nous allons voir comment utiliser le VLOOKUP dans Excel à l'aide de nombreux exemples détaillés, étape par étape. Vous apprendrez comment effectuer un VLOOKUP à partir d'une autre feuille et d'un autre classeur, comment effectuer une recherche avec des caractères génériques, et bien plus encore.

Cet article est le premier d'une série consacrée à la fonction VLOOKUP, l'une des fonctions les plus utiles d'Excel, mais aussi l'une des plus complexes et des moins bien comprises. Nous essaierons d'expliquer les bases dans un langage très simple afin de faciliter l'apprentissage d'un utilisateur inexpérimenté. Nous fournirons également des exemples de formules qui couvrent les utilisations les plus typiques de VLOOKUP dans Excel, et nous essaierons de faire en sorte que l'utilisateur comprenne bien la fonction.Ils sont à la fois instructifs et amusants.

Fonction VLOOKUP d'Excel

Qu'est-ce que la fonction VLOOKUP ? Pour commencer, il s'agit d'une fonction Excel :) Que fait-elle ? Elle recherche la valeur que vous spécifiez et renvoie une valeur correspondante dans une autre colonne. Plus techniquement, la fonction VLOOKUP recherche une valeur dans la première colonne d'une plage donnée et renvoie une valeur dans la même ligne à partir d'une autre colonne.

Dans son utilisation courante, Excel VLOOKUP recherche dans votre ensemble de données sur la base de l'identifiant unique et vous apporte un élément d'information associé à cet identifiant unique.

La lettre "V" signifie "vertical" et est utilisée pour différencier VLOOKUP de la fonction HLOOKUP qui recherche une valeur dans une ligne plutôt que dans une colonne (H signifie "horizontal").

Cette fonction est disponible dans toutes les versions d'Excel 365 à Excel 2007.

Conseil : dans Excel 365 et Excel 2021, vous pouvez utiliser la fonction XLOOKUP, qui est un successeur plus flexible et plus puissant de VLOOKUP.

Syntaxe VLOOKUP

La syntaxe de la fonction VLOOKUP est la suivante :

VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])

Où :

• Valeur de la recherche (obligatoire) - est la valeur à rechercher.

  Il peut s'agir d'une valeur (nombre, date ou texte), d'une référence de cellule (référence à une cellule contenant une valeur de consultation) ou de la valeur renvoyée par une autre fonction. Contrairement aux nombres et aux références de cellules, les valeurs de texte doivent toujours être placées entre "guillemets".

• Table_array (obligatoire) - est la plage de cellules dans laquelle il faut rechercher la valeur de référence et à partir de laquelle il faut récupérer une correspondance. La fonction VLOOKUP recherche toujours dans la première colonne du tableau de la table qui peut contenir diverses valeurs textuelles, des chiffres, des dates et des valeurs logiques.
• Col_index_num (obligatoire) - est le numéro de la colonne à partir de laquelle retourner une valeur. Le comptage commence à partir de la colonne la plus à gauche dans le tableau, qui est 1.
• Recherche de plage (facultatif) - détermine s'il faut rechercher une correspondance approximative ou exacte :
  • TRUE ou omis (par défaut) - correspondance approximative. Si une correspondance exacte n'est pas trouvée, la formule recherche la plus grande valeur inférieure à la valeur de référence. Il faut trier la colonne de référence par ordre croissant.
  • FALSE - correspondance exacte. La formule recherche une valeur exactement égale à la valeur de référence. Si une correspondance exacte n'est pas trouvée, une valeur #N/A est renvoyée.

Formule VLOOKUP de base

Voici un exemple de la formule Excel VLOOKUP dans sa forme la plus simple. Regardez la formule ci-dessous et essayez de la "traduire" en anglais :

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Le 1er argument ( valeur de la recherche ) indique clairement que la formule recherche le mot "lion".
• Le 2ème argument ( tableau_réseau ) est A2:B11. En gardant à l'esprit que la recherche est effectuée dans la colonne la plus à gauche, vous pouvez lire la formule ci-dessus un peu plus loin : rechercher "lion" dans la plage A2:A11. Jusqu'ici, tout va bien, non ?
• Le 3ème argument col_index_num est 2, ce qui signifie que nous voulons renvoyer une valeur correspondante de la colonne B, qui est la deuxième dans le tableau.
• Le 4ème argument recherche de plage est FAUX, ce qui indique que nous recherchons une correspondance exacte.

Une fois tous les arguments établis, vous ne devriez pas avoir de problème à lire l'ensemble de la formule : rechercher "lion" dans A2:A11, trouver une correspondance exacte et renvoyer une valeur de la colonne B de la même ligne.

Pour des raisons de commodité, vous pouvez taper la valeur qui vous intéresse dans une cellule, par exemple E1, remplacer le texte "codé en dur" par la référence de la cellule et faire en sorte que la formule recherche toute valeur que vous saisissez dans E1 :

=VLOOKUP(E1, A2:B11, 2, FALSE)

Si quelque chose n'est pas clair, essayez de le voir de cette façon :

Lorsque vous utilisez des formules VLOOKUP dans des feuilles de calcul réelles, la principale règle à suivre est la suivante : tableau de la table de verrouillage avec des références de cellule absolues (comme $A$2:$C$11) pour éviter qu'elle ne change lors de la copie d'une formule dans d'autres cellules.

Le site valeur de consultation dans la plupart des cas, doit être une référence relative (comme E2) ou vous pouvez verrouiller uniquement la coordonnée de la colonne ($E2). Lorsque la formule est copiée dans la colonne, la référence s'ajuste automatiquement pour chaque ligne.

Pour voir comment cela fonctionne en pratique, veuillez considérer l'exemple suivant. Dans notre tableau d'exemple, nous avons ajouté une colonne supplémentaire qui classe les animaux par vitesse (colonne A) et nous voulons trouver le 1er, le 5ème et le 10ème sprinter le plus rapide du monde. Pour cela, entrez les rangs de recherche dans certaines cellules (E2:E4 dans la capture d'écran ci-dessous), et utilisez les formules suivantes :

Pour tirer les noms des animaux de la colonne B :

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Pour extraire la vitesse de la colonne C :

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Saisissez les formules ci-dessus dans les cellules F2 et G2, sélectionnez ces cellules et faites glisser les formules vers les lignes inférieures :

Si vous examinez la formule dans une ligne inférieure, vous remarquerez que la référence de la valeur de consultation a été ajustée pour cette ligne spécifique, alors que le tableau de la table est inchangé :

Vous trouverez ci-dessous quelques autres conseils utiles qui vous épargneront bien des maux de tête et du temps de dépannage.

Excel VLOOKUP - 5 choses à retenir !

1. La fonction VLOOKUP ne peut pas regarder à sa gauche Il cherche toujours dans le colonne la plus à gauche Si vous avez besoin de tirer des valeurs de la gauche, utilisez la combinaison INDEX MATCH (ou INDEX XMATCH dans Excel 365) qui ne se soucie pas du positionnement des colonnes de recherche et de retour.
2. La fonction VLOOKUP est insensible à la casse. Pour distinguer la casse des lettres, utilisez des formules VLOOKUP sensibles à la casse.
3. N'oubliez pas l'importance du dernier paramètre. Utilisez TRUE pour une correspondance approximative et FALSE pour une correspondance exacte. Pour plus de détails, veuillez consulter VLOOKUP TRUE vs. FALSE.
4. Lorsque vous recherchez une correspondance approximative, assurez-vous que les données de la colonne de recherche sont triées par ordre croissant.
5. Si la valeur de consultation n'est pas trouvée, une erreur #N/A est renvoyée. Pour plus d'informations sur les autres erreurs, veuillez consulter la section Pourquoi Excel VLOOKUP ne fonctionne pas.

Exemples de VLOOKUP dans Excel

J'espère que le lookup vertical commence à vous sembler un peu plus familier. Pour renforcer vos connaissances, construisons quelques autres formules VLOOKUP.

Comment faire un Vlookup à partir d'une autre feuille dans Excel ?

Dans la pratique, la fonction Excel VLOOKUP est rarement utilisée avec des données figurant dans la même feuille de calcul. Le plus souvent, vous devrez extraire les données correspondantes d'une autre feuille de calcul.

Pour effectuer un Vlookup à partir d'une feuille Excel différente, mettez le nom de la feuille de calcul suivi d'un point d'exclamation dans le champ tableau_réseau Par exemple, pour effectuer une recherche dans la plage A2:B10 de la feuille 2, utilisez cette formule :

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Bien entendu, il n'est pas nécessaire de taper le nom de la feuille manuellement. Il suffit de commencer à taper la formule et, lorsqu'on arrive à la ligne tableau_réseau passez à la feuille de calcul de la consultation et sélectionnez la plage à l'aide de la souris.

Par exemple, voici comment vous pouvez rechercher la valeur A2 dans la plage A2:A9 sur l'écran de l'ordinateur. Prix et renvoie une valeur correspondante de la colonne C :

=VLOOKUP(A2, Prix!$A$2:$C$9, 3, FALSE)

Notes :

• Si le nom de la feuille de calcul contient espaces ou caractères non alphabétiques il doit être placé entre guillemets simples, par exemple "Liste de prix"!$A$2:$C$9.
• Si vous utilisez une formule VLOOKUP pour plusieurs cellules, pensez à verrouiller table_array avec le signe $, comme $A$2:$C$9.

Comment faire un Vlookup à partir d'un autre classeur dans Excel ?

Pour effectuer un Vlookup à partir d'un autre classeur Excel, placez le nom du classeur entre crochets avant le nom de la feuille de calcul.

Par exemple, voici la formule permettant de rechercher la valeur A2 sur la feuille nommée Prix dans le Liste_de_prix.xlsx cahier d'exercices :

=VLOOKUP(A2, [Price_List.xlsx]Prix!$A$2:$C$9, 3, FALSE)

Si le nom d'un classeur ou d'une feuille de calcul contient des espaces ou des caractères non alphabétiques, vous devez les placer entre guillemets simples comme ceci :

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

La façon la plus simple de créer une formule VLOOKUP qui fait référence à un classeur différent est la suivante :

1. Ouvrez les deux fichiers.
2. Commencez à taper votre formule, passez à l'autre classeur et sélectionnez le tableau à l'aide de la souris.
3. Saisissez les arguments restants et appuyez sur la touche Entrée pour compléter votre formule.

Le résultat ressemblera à la capture d'écran ci-dessous :

Une fois que vous fermer le fichier contenant votre table de consultation, la formule VLOOKUP continuera à fonctionner, mais elle affichera désormais le chemin complet du classeur fermé :

Pour plus d'informations, veuillez consulter la section Comment faire référence à une autre feuille Excel ou à un autre classeur.

Comment faire un Vlookup à partir d'une plage nommée dans une autre feuille ?

Si vous prévoyez d'utiliser la même plage de consultation dans plusieurs formules, vous pouvez créer une plage nommée pour celle-ci et saisir le nom directement dans le champ tableau_réseau argument.

Pour créer une plage nommée, il suffit de sélectionner les cellules et de taper le nom que vous souhaitez dans le champ Nom Pour les étapes détaillées, veuillez consulter la section Comment nommer une plage dans Excel.

Pour cet exemple, nous avons donné le nom Prix_2020 aux cellules de données (A2:C9) dans la feuille de consultation et obtenez cette formule compacte :

=VLOOKUP(A2, Prices_2020, 3, FALSE)

La plupart des noms dans Excel s'appliquent au cahier complet Vous n'avez donc pas besoin de spécifier le nom de la feuille de calcul lorsque vous utilisez des plages nommées.

Si la gamme nommée est dans un autre classeur pour mettre le nom du classeur avant le nom de la plage, par exemple :

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

De telles formules sont beaucoup plus compréhensibles, n'est-ce pas ? En outre, l'utilisation de plages nommées peut être une bonne alternative aux références absolues. Comme une plage nommée ne change pas, vous pouvez être sûr que votre tableau restera verrouillé, quel que soit l'endroit où la formule est déplacée ou copiée.

Si vous avez converti votre plage de consultation en un tableau Excel pleinement fonctionnel, vous pouvez alors effectuer un Vlookup basé sur le nom du tableau, par ex. Tableau des prix dans la formule ci-dessous :

=VLOOKUP(A2, Price_table, 3, FALSE)

Les références de table, également appelées références structurées, sont résistantes et insensibles à de nombreuses manipulations de données. Par exemple, vous pouvez supprimer ou ajouter de nouvelles lignes à votre table de consultation sans vous soucier de la mise à jour des références.

Utilisation de caractères de remplacement dans une formule VLOOKUP

Comme de nombreuses autres formules, la fonction Excel VLOOKUP accepte les caractères génériques suivants :

• Point d'interrogation ( ?) pour correspondre à n'importe quel caractère unique.
• Astérisque (*) pour correspondre à toute séquence de caractères.

Les caractères génériques s'avèrent très utiles dans de nombreuses situations :

• Lorsque vous ne vous souvenez pas du texte exact que vous recherchez.
• Lorsque vous recherchez une chaîne de texte qui fait partie du contenu de la cellule.
• Lorsqu'une colonne de consultation contient des espaces en tête ou en queue de colonne, vous pouvez vous creuser la tête pour comprendre pourquoi une formule normale ne fonctionne pas.

Exemple 1 : Recherche d'un texte commençant ou se terminant par certains caractères.

Supposons que vous vouliez trouver un certain client dans la base de données ci-dessous. Vous ne vous souvenez pas de son nom de famille, mais vous êtes sûr qu'il commence par "ack".

Pour obtenir le nom de famille de la colonne A, utilisez la formule générique Vlookup suivante :

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Pour récupérer la clé de licence de la colonne B, utilisez celle-ci (la différence réside uniquement dans le numéro d'index de la colonne) :

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Vous pouvez également saisir la partie connue du nom dans une cellule, par exemple E1, et combiner le caractère générique avec la référence de la cellule :

=VLOOKUP(E1& ; "*", $A$2:$B$10, 1, FALSE)

La capture d'écran ci-dessous montre les résultats :

Vous trouverez ci-dessous quelques autres formules VLOOKUP avec des caractères génériques.

Trouvez le nom de famille se terminant par "fils" :

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Obtenez le nom qui commence par "joh" et finit par "son" :

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Tirez un nom de famille à 5 caractères :

=VLOOKUP(" ?????", $A$2:$B$10, 1, FALSE)

Exemple 2 : VLOOKUP joker basé sur la valeur de la cellule

Grâce à l'exemple précédent, vous savez déjà qu'il est possible de concaténer une esperluette (& ;) et une référence de cellule pour créer une chaîne de recherche. Pour trouver une valeur contenant un ou plusieurs caractères donnés à n'importe quelle position, placez une esperluette avant et après la référence de cellule.

Supposons que vous souhaitiez obtenir un nom correspondant à une certaine clé de licence, mais que vous ne connaissiez pas toute la clé, seulement quelques caractères. Avec les clés dans la colonne A, les noms dans la colonne B et une partie de la clé cible dans E1, vous pouvez effectuer un Vlookup avec un caractère de remplacement de cette manière :

Extraire la clé :

=VLOOKUP("*"&E1& ; "*", $A$2:$B$10, 1, FALSE)

Extraire le nom :

=VLOOKUP("*"&E1& ; "*", $A$2:$B$10, 2, FALSE)

Notes :

• Pour qu'une formule VLOOKUP joker fonctionne correctement, utilisez une correspondance exacte (FALSE est le dernier argument).
• Si plus d'une correspondance est trouvée, la première est retournée. .

VLOOKUP VRAI vs FAUX

Et maintenant, il est temps d'examiner de plus près le dernier argument de la fonction Excel VLOOKUP. Bien qu'il soit facultatif, l'argument recherche de plage est très important : selon que vous choisissez VRAI ou FAUX, votre formule peut donner des résultats différents.

Excel VLOOKUP correspondance exacte (FALSE)

Si recherche de plage a la valeur FALSE, une formule Vlookup recherche une valeur qui est exactement égale à la valeur de recherche. Si deux correspondances ou plus sont trouvées, la première est renvoyée. Si une correspondance exacte n'est pas trouvée, l'erreur #N/A se produit.

Excel VLOOKUP correspondance approximative (VRAI)

Si recherche de plage Plus précisément, elle recherche d'abord une correspondance exacte et, si elle ne trouve pas de correspondance exacte, elle recherche la plus grande valeur suivante qui est inférieure à la valeur de recherche.

Un Vlookup à correspondance approximative fonctionne avec les réserves suivantes :

• La colonne de consultation doit être triée en ordre ascendant de la plus petite à la plus grande, sinon on risque de ne pas trouver une valeur correcte.
• Si la valeur recherchée est inférieure à la plus petite valeur du tableau de recherche, une erreur #N/A est renvoyée.

Les exemples suivants vous aideront à mieux comprendre la différence entre une Vlookup à correspondance exacte et une Vlookup à correspondance approximative, ainsi que le moment où il est préférable d'utiliser chaque formule.

Exemple 1 : Comment effectuer une Vlookup à correspondance exacte ?

Pour rechercher une correspondance exacte, il suffit de mettre FALSE dans le dernier argument.

Pour cet exemple, prenons le tableau des vitesses des animaux, intervertissons les colonnes et essayons de trouver les animaux qui peuvent courir à 80, 50 et 30 miles par heure. Avec les valeurs de recherche dans D2, D3 et D4, entrez la formule ci-dessous dans E2, puis copiez-la dans deux autres cellules :

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Comme vous pouvez le constater, la formule renvoie "Lion" dans E3, car ils fonctionnent exactement 50 fois par heure. Pour les deux autres valeurs de recherche, une correspondance exacte n'est pas trouvée, et des erreurs #N/A apparaissent.

Exemple 2 : Comment faire un Vlookup pour une correspondance approximative ?

Pour rechercher une correspondance approximative, il y a deux choses essentielles que vous devez faire :

• Trier la première colonne de tableau_réseau du plus petit au plus grand.
• Utilisez TRUE pour le recherche de plage ou l'omettre.

Le tri de la colonne de recherche est très important car la fonction VLOOKUP arrête la recherche dès qu'elle trouve une correspondance proche inférieure à la valeur de recherche. Si les données ne sont pas triées correctement, vous risquez d'obtenir des résultats vraiment étranges ou un grand nombre d'erreurs #N/A.

Pour notre échantillon de données, une formule Vlookup de correspondance approximative est la suivante :

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Et renvoie les résultats suivants :

• Pour une valeur de référence de "80", "Cheetah" est renvoyé car sa vitesse (70) est la plus proche de la valeur de référence et est inférieure à celle-ci.
• Pour une valeur de recherche de "50", une correspondance exacte est retournée (Lion).
• Pour une valeur de référence de "30", une erreur #N/A est renvoyée car la valeur de référence est inférieure à la plus petite valeur de la colonne de référence.

Outils spéciaux pour Vlookup dans Excel

Sans aucun doute, VLOOKUP est l'une des fonctions Excel les plus puissantes et les plus utiles, mais c'est aussi l'une des plus déroutantes. Pour rendre la courbe d'apprentissage moins raide et l'expérience plus agréable, nous avons inclus quelques outils permettant de gagner du temps dans notre Suite ultime pour Excel.

Assistant VLOOKUP - un moyen facile d'écrire des formules complexes

L'assistant VLOOKUP interactif vous guidera à travers les options de configuration afin de construire une formule parfaite pour les critères que vous spécifiez. Selon la structure de vos données, il utilisera la fonction VLOOKUP standard ou une formule INDEX MATCH qui peut extraire des valeurs à gauche.

Pour obtenir votre formule sur mesure, voici ce que vous devez faire :

1. Exécutez l'assistant VLOOKUP.

1. Choisissez votre table principale et votre table de consultation.
2. Spécifiez les colonnes suivantes (dans de nombreux cas, elles sont choisies automatiquement) :
   • Colonne clé - la colonne de votre tableau principal contenant les valeurs à rechercher.
   • Colonne de recherche - la colonne à regarder en face.
   • Colonne de retour - la colonne à partir de laquelle les valeurs doivent être récupérées.
3. Cliquez sur le bouton Insérer bouton.

Les exemples suivants montrent l'assistant en action.

Vlookup standard

Lorsque la colonne de recherche ( Animal ) est la colonne la plus à gauche dans la table de recherche, une formule VLOOKUP normale pour une correspondance exacte est insérée :

Vlookup à gauche

Lorsque la colonne de recherche ( Animal ) se trouve à droite de la colonne de retour ( Vitesse ), l'assistant insère une formule INDEX MATCH pour Vlookup de droite à gauche :

Bonus supplémentaire ! Grâce à l'utilisation astucieuse des références de cellules, les formules peuvent être copiées ou déplacées dans n'importe quelle colonne, sans que vous ayez à mettre à jour les références.

Fusionner deux tableaux - alternative sans formule à Excel VLOOKUP

Si vos fichiers Excel sont extrêmement volumineux et complexes, que l'échéance du projet est imminente et que vous cherchez quelqu'un qui puisse vous donner un coup de main, essayez l'assistant de fusion de tableaux.

Cet outil est notre alternative visuelle et sans stress à la fonction VLOOKUP d'Excel, qui fonctionne de cette manière :

1. Sélectionnez votre table principale.
2. Sélectionnez la table de consultation.
3. Choisissez une ou plusieurs colonnes communes comme identifiant(s) unique(s).
4. Spécifiez les colonnes à mettre à jour.
5. En option, choisissez les colonnes à ajouter.
6. Laissez à l'assistant de fusion de tableaux quelques secondes pour le traitement... et appréciez les résultats :)

Dans la prochaine partie de notre tutoriel, nous aborderons des exemples de VLOOKUP avancés qui vous apprendront à effectuer une Vlookup sur plusieurs critères, à retourner toutes les correspondances ou la Nième occurrence, à effectuer une double Vlookup, à effectuer une recherche sur plusieurs feuilles avec une seule formule, et bien plus encore. Je vous remercie de votre lecture et j'espère vous voir la semaine prochaine !

Téléchargements disponibles

Exemples de formules Excel VLOOKUP (fichier .xlsx)

Ultimate Suite 14 jours version entièrement fonctionnelle (fichier .exe)